3.1 Percentage arbeidsovereenkomsten voor bepaalde tijd op een peildatum

Concepten

• Arbeidsovereenkomst bepaalde tijd
• Arbeidsovereenkomst onbepaalde tijd
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 3.1
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12	(?vestiging AS ?Organisatie_niveau)
13    # ?zorgkantoor_vestiging
14    (SUM(?bepaald) AS ?Aantal_arbeidsovereenkomsten_bepaalde_tijd)
15    (SUM(?onbepaald) AS ?Aantal_arbeidsovereenkomsten_onbepaalde_tijd)
16    (100*?Aantal_arbeidsovereenkomsten_bepaalde_tijd/(?Aantal_arbeidsovereenkomsten_bepaalde_tijd + ?Aantal_arbeidsovereenkomsten_onbepaalde_tijd) AS ?Percentage_bepaalde_tijd)
17
18{     
19    # definieer parameters
20    # BIND("2023-09-12"^^xsd:date AS ?peildatum)
21    # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
22
23    # selecteer personen met arbeidsovereenkomst (on)bepaalde tijd
24    VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomstBepaaldeTijd onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd}
25    ?overeenkomst 
26        a ?type_overeenkomst ;
27        onz-g:hasPart ?overeenkomst_afspraak .
28    ?overeenkomst_afspraak
29        a onz-pers:WerkOvereenkomstAfspraak ;
30        onz-g:startDatum ?start_afspraak .
31    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
32    FILTER(?start_afspraak <= ?peildatum && ((?eind_afspraak >= ?peildatum) || (!BOUND(?eind_afspraak))))
33
34    ?overeenkomst_afspraak onz-g:isAbout ?locatie .
35    ?locatie a onz-g:StationaryArtifact ;
36        onz-g:partOf* ?vestiging_uri .
37    ?vestiging_uri a onz-org:Vestiging ;
38        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
39    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
40    ?pc_gebied 
41        onz-g:identifiedBy ?postcode ;
42        onz-g:partOf+ ?zk_regio .
43    ?zk_regio a onz-org:ZorgkantoorRegio .
44    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
45    {     
46        ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
47        ?vest_nr a onz-org:Vestigingsnummer ;
48            onz-g:hasDataValue ?vestiging .
49    } UNION {
50        # Includeer ook de organisatie als geheel en label deze als vestiging
51        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
52        BIND("Totaal organisatie" AS ?vestiging)
53        BIND("n.v.t." AS ?zk_vestiging)
54    }
55    BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
56
57	BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBepaaldeTijd, 1, 0) AS ?bepaald)
58    BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd, 1, 0) AS ?onbepaald)
59}
60GROUP BY ?vestiging ?zorgkantoor_vestiging
61